plugins {
    id 'com.github.johnrengelman.shadow'
}

def generatedResources = project(':common').file('src/generated')
def existingResources = project(':common').file('src/main/resources')

sourceSets {
    main {
        resources.srcDir generatedResources
    }
}

loom {
    runs {
        data {
            data()
            programArgs "--all", "--mod", "progression"
            programArgs "--output", generatedResources.absolutePath
            programArgs "--existing", existingResources.absolutePath
        }
    }
    forge {
        mixinConfig "progression.mixins.json"
    }
}

architectury {
    platformSetupLoomIde()
    forge()
}

configurations {
    common {
        canBeResolved = true
        canBeConsumed = false
    }
    compileClasspath.extendsFrom common
    runtimeClasspath.extendsFrom common
    developmentForge.extendsFrom common

    // Files in this configuration will be bundled into your mod using the Shadow plugin.
    // Don't use the `shadow` configuration from the plugin itself as it's meant for excluding files.
    shadowBundle {
        canBeResolved = true
        canBeConsumed = false
    }
}

repositories {

    maven {
        url "https://www.cursemaven.com"
        content {
            includeGroup "curse.maven"
        }
    }
//  maven {
//    name = "Team Resourceful Maven"
//    url = "https://maven.teamresourceful.com/repository/maven-public/"
//  }
    maven {
        name = 'tterrag maven'
        url = 'https://maven.tterrag.com/'
    }
    exclusiveContent {
        forRepository {
            maven {
                name = "Modrinth"
                url = "https://api.modrinth.com/maven"
            }
        }
        filter {
            includeGroup "maven.modrinth"
        }
    }
    maven { url "https://maven.shedaniel.me/" }
}

dependencies {
    forge "net.minecraftforge:forge:$rootProject.forge_version"
    modImplementation "dev.architectury:architectury-forge:$rootProject.architectury_api_version"

    modImplementation "curse.maven:simplyswords-659887:5639538"

    modLocalRuntime "me.shedaniel.cloth:cloth-config-forge:$rootProject.cloth_config_version"
    localRuntime(include("io.github.llamalad7:mixinextras-forge:0.4.1"))
    modLocalRuntime "curse.maven:better-combat-by-daedelus-639842:5625757"
    modLocalRuntime "curse.maven:playeranimator-658587:4587214"
    modLocalRuntime "com.tterrag.registrate:Registrate:$rootProject.registrate_version"
    modLocalRuntime "com.jozufozu.flywheel:flywheel-forge-$rootProject.minecraft_version:$rootProject.flywheel_version"
    modLocalRuntime("com.simibubi.create:create-$rootProject.minecraft_version:$rootProject.create_version:slim") { transitive = false }
    modLocalRuntime "curse.maven:additional-additions-forge-582387:5155724"
    modLocalRuntime "curse.maven:create-industry-693815:5811638"
//    modCompileOnly "curse.maven:create-industry-693815:5811638"
    modLocalRuntime "curse.maven:create-deep-dark-1020173:5868515"
    modLocalRuntime "maven.modrinth:purecoppertools:UhYKtKPC"


    modLocalRuntime "curse.maven:emi-580555:6205514"

    common(project(path: ':common', configuration: 'namedElements')) { transitive false }
    shadowBundle project(path: ':common', configuration: 'transformProductionForge')
}

processResources {
    inputs.property 'version', project.version

    filesMatching('META-INF/mods.toml') {
        expand version: project.version
    }
}

shadowJar {
    configurations = [project.configurations.shadowBundle]
    archiveClassifier = 'dev-shadow'
}

remapJar {
    inputFile.set shadowJar.archiveFile
}